cmake_minimum_required(VERSION 3.5)

find_program(GIT_PROGRAM git)
find_program(CCACHE_PROGRAM ccache)
find_program(PYTHON_PROGRAM python3)

set(program_name fred-backend-registry)

if(NOT SERVER_VERSION)
    if(NOT GIT_PROGRAM)
        message(FATAL_ERROR "git not found; you need to pass -DSERVER_VERSION=")
    endif()
    execute_process(COMMAND ${GIT_PROGRAM} "describe" "--tags"
                    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
                    OUTPUT_VARIABLE SERVER_VERSION)
endif()
string(STRIP "${SERVER_VERSION}" SERVER_VERSION)

# XXX: Temporary server and api version variables trim (used in diagnostics api)
# Will be removed after api and impl. are changed to more relaxed format
string(REGEX MATCH "^([0-9]+.[0-9]+.[0-9]+)" SERVER_VERSION ${SERVER_VERSION})

message(STATUS "SERVER_VERSION: ${SERVER_VERSION}")

set(TARBALL_FILE_NAME "${program_name}-${SERVER_VERSION}")

if(CCACHE_PROGRAM)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

string(REGEX MATCH "^([0-9]+.[0-9]+.[0-9]+)" SERVER_VERSION_MAJOR_MINOR_PATCH ${SERVER_VERSION})
project(FredRegistryServices
    VERSION ${SERVER_VERSION_MAJOR_MINOR_PATCH}
    LANGUAGES CXX)
message(STATUS "PROJECT_VERSION: ${PROJECT_VERSION}")

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

set_default(CMAKE_BUILD_TYPE "Release")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")

set_default(THREADS_PREFER_PTHREAD_FLAG ON)
find_package(Threads REQUIRED)

set_default(CMAKE_EXPORT_COMPILE_COMMANDS ON)

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name} PUBLIC
            ${CMAKE_CURRENT_SOURCE_DIR}
            ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PUBLIC "-ggdb"
            PUBLIC "-grecord-gcc-switches"
            PUBLIC "-Wall"
            PUBLIC "-Wextra"
            PUBLIC "-fdiagnostics-color=auto")
    endforeach()
endfunction()

function(set_grpc_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_compile_options(${target_name}
            PUBLIC "-Wno-unused-parameter")
    endforeach()
endfunction()

function(set_local_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_include_directories(${target_name} PUBLIC
            ${libfred_INCLUDE_DIRS})
    endforeach()
endfunction()

find_package(Boost 1.53.0
    COMPONENTS
    program_options
    unit_test_framework
    REQUIRED)
find_package(PkgConfig REQUIRED)

set_default(LIBFRED_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/libfred)
if(NOT IS_ABSOLUTE ${LIBFRED_DIR})
    set(LIBFRED_DIR ${CMAKE_BINARY_DIR}/${LIBFRED_DIR})
endif()
if(NOT EXISTS ${LIBFRED_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBFRED_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBFRED_DIR")
endif()

if(NOT TARGET fred::library)
    add_subdirectory(${LIBFRED_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/libfred EXCLUDE_FROM_ALL)
endif()

set_default(API_REGISTRY_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/api/registry)
if(NOT IS_ABSOLUTE ${API_REGISTRY_DIR})
    set(API_REGISTRY_DIR ${CMAKE_BINARY_DIR}/${API_REGISTRY_DIR})
endif()
if(NOT EXISTS ${API_REGISTRY_DIR}/build/c++.cmake)
    message(FATAL_ERROR "${API_REGISTRY_DIR}/build/c++.cmake does not exist; you need to pass -DAPI_REGISTRY_DIR")
endif()

include("${API_REGISTRY_DIR}/build/c++.cmake")

# XXX: Temporary server and api version variables trim (used in diagnostics api)
# Will be removed after api and impl. are changed to more relaxed format
string(STRIP "${API_VERSION}" API_VERSION)
string(REGEX MATCH "^([0-9]+.[0-9]+.[0-9]+)" API_VERSION ${API_VERSION})
message(STATUS "API_VERSION: ${API_VERSION}")

macro(normalize_path variable_name variable_value)
    string(REGEX REPLACE "//*" "/" "${variable_name}" "${variable_value}")
    if(NOT "x${${variable_name}}" STREQUAL "x/")
        string(REGEX REPLACE "/$" "" "${variable_name}" "${${variable_name}}")
    endif()
endmacro()

macro(set_default_path variable_name variable_value)
    if(NOT ${variable_name})
        normalize_path(${variable_name} ${variable_value})
    endif()
endmacro()

normalize_path(NORMALIZED_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
if("x${NORMALIZED_INSTALL_PREFIX}" STREQUAL "x/usr/local")
    set(USR_PREFIX "")
    set(USR_SHARE_PREFIX "")
else()
    set(USR_SHARE_PREFIX "/usr")
    if(USE_USR_PREFIX)
        set(USR_PREFIX "/usr")
    else()
        set(USR_PREFIX "")
    endif()
endif()

set_default_path(BINDIR ${CMAKE_INSTALL_PREFIX}/${USR_PREFIX}/bin)
set_default_path(SBINDIR ${CMAKE_INSTALL_PREFIX}/${USR_PREFIX}/sbin)

set_default(PACKAGE fred-registry-services)
set_default(HAVE_BOOST_SERIALIZATION 1)
set_default(HAVE_LOGGER 1)

set_default(VERSION ${PROJECT_VERSION})
configure_file(config.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)

set(REGISTRY_SOURCES
    src/cfg.cc
    src/exceptions.cc
    src/fred_unwrap.cc
    src/fred_wrap.cc
    src/main.cc
    src/proto_unwrap.cc
    src/proto_wrap.cc
    src/contact/contact_common_types.cc
    src/contact/contact_data_history.cc
    src/contact/contact_handle_history.cc
    src/contact/contact_history_interval.cc
    src/contact/contact_info.cc
    src/contact/contact_state.cc
    src/contact/contact_state_flags.cc
    src/contact/contact_state_history.cc
    src/contact/search_contact.cc
    src/diagnostics/about.cc
    src/diagnostics/about_reply.cc
    src/diagnostics/ping.cc
    src/diagnostics/ping_reply.cc
    src/diagnostics/ping_request.cc
    src/domain/domain_common_types.cc
    src/domain/domain_data_history.cc
    src/domain/domain_history_interval.cc
    src/domain/domain_info.cc
    src/domain/domain_info_reply.cc
    src/domain/domain_info_request.cc
    src/domain/domain_state.cc
    src/domain/domain_state_flags.cc
    src/domain/domain_state_history.cc
    src/domain/fqdn_history.cc
    src/domain/search_domain.cc
    src/keyset/keyset_common_types.cc
    src/keyset/keyset_data_history.cc
    src/keyset/keyset_handle_history.cc
    src/keyset/keyset_history_interval.cc
    src/keyset/keyset_info.cc
    src/keyset/keyset_info_reply.cc
    src/keyset/keyset_info_request.cc
    src/keyset/keyset_state.cc
    src/keyset/keyset_state_flags.cc
    src/keyset/keyset_state_history.cc
    src/keyset/search_keyset.cc
    src/nsset/nsset_common_types.cc
    src/nsset/nsset_data_history.cc
    src/nsset/nsset_handle_history.cc
    src/nsset/nsset_history_interval.cc
    src/nsset/nsset_info.cc
    src/nsset/nsset_info_reply.cc
    src/nsset/nsset_info_request.cc
    src/nsset/nsset_state.cc
    src/nsset/nsset_state_flags.cc
    src/nsset/nsset_state_history.cc
    src/nsset/search_nsset.cc
    src/object/object_common_types.cc
    src/registrar/registrar_common_types.cc
    src/registrar/registrar_credit.cc
    src/registrar/registrar_info.cc
    src/registrar/registrar_list.cc
    src/registrar/registrar_zone_access.cc
    src/util/into.cc
    src/util/sql_exec_in_thread.cc
    src/util/struct_to_string.cc)

add_library(registry-static STATIC ${REGISTRY_SOURCES})
add_library(registry-static::library ALIAS registry-static)

add_library(fred-registry-services-iface-static STATIC
    ${FRED_REGISTRY_PROTO_SRCS}
    ${FRED_REGISTRY_GRPC_SRCS})
add_library(fred-registry-services-iface-static::library ALIAS
    fred-registry-services-iface-static)

add_executable(fred-registry-services
    src/main.cc)
target_link_libraries(fred-registry-services PRIVATE
    fred-registry-services-iface-static::library
    gRPC::grpc++_reflection
    protobuf::libprotobuf
    registry-static::library
    fred-static::library
    ${Boost_PROGRAM_OPTIONS_LIBRARY}
    Threads::Threads
    ${libfred_LIBRARIES})

add_executable(test-fred-registry-services
    test/main.cc
    test/setup/fixture/cfg.cc
    test/setup/fixture/contact.cc
    test/setup/fixture/registrar.cc
    test/contact/test_search_contact.cc
    test/domain/test_search_domain.cc
    test/keyset/test_search_keyset.cc
    test/nsset/test_search_nsset.cc)
target_link_libraries(test-fred-registry-services PRIVATE
    registry-static::library
    fred-static::library
    ${Boost_PROGRAM_OPTIONS_LIBRARY}
    ${Boost_UNIT_TEST_FRAMEWORK_LIBRARY}
    Threads::Threads
    ${libfred_LIBRARIES})

set_common_properties_on_targets(
    fred-registry-services-iface-static
    fred-registry-services
    registry-static
    test-fred-registry-services)

set_local_properties_on_targets(
    fred-registry-services
    registry-static
    test-fred-registry-services)

set_grpc_properties_on_targets(
    fred-registry-services-iface-static)

if("${CMAKE_BUILD_TYPE}" STREQUAL "Release")
    message(STATUS "Generating python bindings is disabled in a Release build; use -DCMAKE_BUILD_TYPE=Debug instead")
elseif(NOT PYTHON_PROGRAM)
    message(FATAL_ERROR ${PYTHON_PROGRAM} " not found")
else()
    add_custom_target(compile_to_python ALL ${PYTHON_PROGRAM} setup.py build && cp -a fred_api ../..
        WORKING_DIRECTORY ${API_REGISTRY_DIR})
endif()

install(TARGETS ${PACKAGE} DESTINATION ${SBINDIR})
install(TARGETS test-${PACKAGE} DESTINATION ${BINDIR})
if(NOT TARGET uninstall)
    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < install_manifest.txt
        COMMAND cat install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty
        COMMAND rm install_manifest.txt
        WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
endif()

if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/.git AND GIT_PROGRAM)
    if(NOT TARGET dist)
        add_custom_target(dist_api_registry
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/api/registry/ HEAD > ${CMAKE_CURRENT_BINARY_DIR}/.api-registry.tar
            WORKING_DIRECTORY ${API_REGISTRY_DIR})
        add_custom_target(dist_libfred
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/libfred/ HEAD > ${CMAKE_CURRENT_BINARY_DIR}/.libfred.tar
            WORKING_DIRECTORY ${LIBFRED_DIR})
        add_custom_command(OUTPUT ${TARBALL_FILE_NAME}.tar.gz
            COMMAND ${GIT_PROGRAM} -C ${CMAKE_CURRENT_SOURCE_DIR} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > .${TARBALL_FILE_NAME}.tar
            COMMAND tar --concatenate --file=.${TARBALL_FILE_NAME}.tar .libfred.tar
            COMMAND tar --concatenate --file=.${TARBALL_FILE_NAME}.tar .api-registry.tar
            COMMAND cat .${TARBALL_FILE_NAME}.tar | gzip > ${TARBALL_FILE_NAME}.tar.gz
            COMMAND rm .${TARBALL_FILE_NAME}.tar .libfred.tar .api-registry.tar
            DEPENDS dist_api_registry dist_libfred
            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
            COMMENT "Make tarball ${CMAKE_CURRENT_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz")
        add_custom_target(dist DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz)
    endif()

    if(DEFINED ENV{DISTCHECK_CMAKE_FLAGS})
        set(distcheck_flags $ENV{DISTCHECK_CMAKE_FLAGS})
    endif()

    if(NOT TARGET distcheck)
        set(DISTCHECK_BUILD_DIR "_build")
        set(DISTCHECK_INSTALL_DIR "_inst")
        if(${CMAKE_GENERATOR} STREQUAL "Ninja")
            set(DISTCHECK_BUILD_CMD "ninja")
        else()
            set(DISTCHECK_BUILD_CMD "$(MAKE)")
        endif()
        add_custom_target(distcheck_prepare
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
            COMMENT "Clean previous distcheck")
        add_custom_target(distcheck_make_build_and_install_dirs
            COMMAND mkdir ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR}
            DEPENDS distcheck_prepare
            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
            COMMENT "Make build and install directories")
        add_custom_target(distcheck_unpack_tarball
            COMMAND tar xzf ${TARBALL_FILE_NAME}.tar.gz
            DEPENDS distcheck_make_build_and_install_dirs dist
            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
            COMMENT "Unpack tarball ${TARBALL_FILE_NAME}.tar.gz")
        add_custom_target(distcheck_configure
            COMMAND ${CMAKE_COMMAND} -G${CMAKE_GENERATOR} ${distcheck_flags} -DCMAKE_INSTALL_PREFIX=../${DISTCHECK_INSTALL_DIR} ../${TARBALL_FILE_NAME}
            DEPENDS distcheck_unpack_tarball
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR}
            COMMENT "Configure ${PROJECT_NAME}")
        add_custom_target(distcheck_build
            COMMAND ${DISTCHECK_BUILD_CMD}
            DEPENDS distcheck_configure
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR}
            COMMENT "Build ${PROJECT_NAME}")
        add_custom_target(distcheck_install
            COMMAND ${DISTCHECK_BUILD_CMD} install
            DEPENDS distcheck_build
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR}
            COMMENT "Install ${PROJECT_NAME}")
        add_custom_target(distcheck_uninstall
            COMMAND ${DISTCHECK_BUILD_CMD} uninstall
            DEPENDS distcheck_install
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR}
            COMMENT "Uninstall ${PROJECT_NAME}")
        add_custom_target(distcheck_clean
            COMMAND ${DISTCHECK_BUILD_CMD} clean
            DEPENDS distcheck_uninstall
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR}
            COMMENT "Clean ${PROJECT_NAME}")
        add_custom_target(distcheck_remove_dirs
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            DEPENDS distcheck_clean
            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
            COMMENT "Clean after distcheck")
        add_custom_target(distcheck
            DEPENDS distcheck_remove_dirs
            COMMENT "PASS: ${TARBALL_FILE_NAME}.tar.gz is ready for distribution.")
    endif()
else()
    message(STATUS "no git -- not including dist and distcheck targets")
endif()
