cmake_minimum_required(VERSION 3.5)

# compile options

set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Specifies the build type. Possible values are empty, Debug, Release, RelWithDebInfo, MinSizeRel, ...")
# CMAKE_<LANG>_FLAGS_<CONFIG> new in cmake version 3.11
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
option(THREADS_PREFER_PTHREAD_FLAG "The -pthread compiler and linker flag preference." TRUE)
set(SPDLOG_ACTIVE_LEVEL "SPDLOG_LEVEL_TRACE" CACHE STRING "This will turn on/off logging statements at compile time.")
set(FMT_STRING_ALIAS "1" CACHE STRING "Constructs a compile-time format string.")
set(FMT_HEADER_ONLY "1" CACHE STRING "Use fmt library in the header-only manner.")
option(CMAKE_EXPORT_COMPILE_COMMANDS "If enabled, generates a compile_commands.json file containing the exact compiler calls." ON)

macro(append_path output_variable_name)
    foreach(ARG ${ARGN})
        if(${output_variable_name})
            string(APPEND ${output_variable_name} "/${ARG}")
        else()
            set(${output_variable_name} "${ARG}")
        endif()
    endforeach()
    string(REGEX REPLACE "//+" "/" ${output_variable_name} "${${output_variable_name}}")
    string(REGEX REPLACE "(.)/$" "\\1" ${output_variable_name} "${${output_variable_name}}")
endmacro()

macro(concat_path output_variable_name)
    set(concat_path_tmp_variable "")
    append_path(concat_path_tmp_variable ${ARGN})
    set(${output_variable_name} "${concat_path_tmp_variable}" PARENT_SCOPE)
endmacro()

macro(set_default_path variable_name)
    if(NOT ${variable_name})
        set(${variable_name} "")
        append_path(${variable_name} ${ARGN})
    endif()
endmacro()

# project details

include("cmake/package.cmake")

package(fred-logger-services
    FULL_VERSION "1.5.0")

project(FredLoggerServices
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

# build options

option(LOGGER_BUILD_TESTS "Build ${PACKAGE_NAME} tests" OFF)

# package dependencies

include("cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "dependencies.txt")

# dependencies

find_package(Threads REQUIRED)

set(CMAKE_FIND_PACKAGE_PREFER_CONFIG TRUE)
find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
        system
    REQUIRED)

# configuration files

set_default(HAVE_BOOST_SERIALIZATION 1)
set_default_path(DEFAULT_CONFIG_FILE "${CMAKE_INSTALL_FULL_SYSCONFDIR}" fred/fred-logger-services.conf)
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)

add_library(logger-core STATIC
    src/cfg.cc
    src/diagnostics/about.cc
    src/diagnostics/status.cc
    src/exceptions.cc
    src/get_dsn.cc
    src/handle_request.cc
    src/is_monitoring_ip.cc
    src/proto_unwrap.cc
    src/proto_wrap.cc)

add_library(LoggerCore::library ALIAS logger-core)

target_link_libraries(logger-core
    Boost::date_time
    Boost::program_options
    Boost::system
    Threads::Threads
    FredLoggerServicesIface::library
    LibDiagnostics::library
    LibLogger::library
    LibLog::library)

add_library(fred-logger-services-iface STATIC
    ${FRED_LOGGER_PROTO_SRCS}
    ${FRED_LOGGER_GRPC_SRCS})

add_library(FredLoggerServicesIface::library ALIAS fred-logger-services-iface)

add_executable(fred-logger-services
    src/main.cc)

target_link_libraries(fred-logger-services PRIVATE
    FredDiagnosticsServicesIface::library
    LoggerCore::library)

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PUBLIC
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
    endforeach()
endfunction()

function(set_grpc_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_compile_options(${target_name}
            PRIVATE
                "-Wno-unused-parameter"
                "-Wno-array-bounds")
        target_link_libraries(${target_name}
            PUBLIC
                -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state
                protobuf::libprotobuf)
    endforeach()
endfunction()

set_grpc_properties_on_targets(
    fred-logger-services-iface)

set_common_properties_on_targets(
    fred-logger-services-iface
    fred-logger-services
    logger-core)

# tests

if(LOGGER_BUILD_TESTS)
    add_subdirectory(test)
endif()

# installation

include(GNUInstallDirs)

install(TARGETS ${PACKAGE_NAME}
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

add_custom_target(uninstall
    COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
    COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

# dist

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")

list_package_dependencies_recursive("${PACKAGE_NAME}")
