cmake_minimum_required(VERSION 3.5)

find_program(GIT_PROGRAM git)
find_program(CCACHE_PROGRAM ccache)

option(LOGGER_BUILD_TESTS "Build logger tests" OFF)

if(NOT SERVER_VERSION)
    if(NOT GIT_PROGRAM)
        message(FATAL_ERROR "git not found; you need to pass -DSERVER_VERSION=")
    endif()
    execute_process(COMMAND ${GIT_PROGRAM} "describe" "--tags"
                    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
                    OUTPUT_VARIABLE SERVER_VERSION)
endif()
string(STRIP "${SERVER_VERSION}" SERVER_VERSION)

message(STATUS "SERVER_VERSION: ${SERVER_VERSION}")

string(REGEX MATCH "^([0-9]+.[0-9]+.[0-9]+)" SERVER_VERSION ${SERVER_VERSION})
project(FredLoggerServices
    VERSION ${SERVER_VERSION}
    LANGUAGES CXX)
message(STATUS "PROJECT_VERSION: ${PROJECT_VERSION}")

if(CCACHE_PROGRAM)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

set(TARBALL_FILE_NAME "${PROJECT_NAME}-${SERVER_VERSION}")
set(LIBLOGGER_PREFIX ${TARBALL_FILE_NAME}/external/lib/liblogger)

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

set_default(CMAKE_BUILD_TYPE "Release")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set_default(THREADS_PREFER_PTHREAD_FLAG ON)
set_default(SPDLOG_ACTIVE_LEVEL 0)
set_default(FMT_STRING_ALIAS 1)
set_default(FMT_HEADER_ONLY 1)
set_default(CMAKE_EXPORT_COMPILE_COMMANDS ON)

find_package(Threads REQUIRED)
set(Threads_LIBRARIES Threads::Threads)

find_package(Boost 1.53.0
    COMPONENTS
        program_options
        date_time
    REQUIRED)

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PUBLIC
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
        target_compile_definitions(${target_name}
            PRIVATE
                SPDLOG_ACTIVE_LEVEL=${SPDLOG_ACTIVE_LEVEL}
                FMT_STRING_ALIAS=${FMT_STRING_ALIAS}
                FMT_HEADER_ONLY=${FMT_HEADER_ONLY})
    endforeach()
endfunction()

function(set_grpc_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_compile_options(${target_name}
            PRIVATE "-Wno-unused-parameter")
    endforeach()
endfunction()

set_default(LIBLOGGER_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/liblogger)
if(NOT IS_ABSOLUTE ${LIBLOGGER_DIR})
    set(LIBLOGGER_DIR ${CMAKE_BINARY_DIR}/${LIBLOGGER_DIR})
endif()
if(NOT EXISTS ${LIBLOGGER_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBLOGGER_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBLOGGER_DIR")
endif()
if(NOT TARGET LibLogger::library)
    add_subdirectory(${LIBLOGGER_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/liblogger EXCLUDE_FROM_ALL)
endif()

set_default(LIBLOG_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/liblog)
if(NOT IS_ABSOLUTE ${LIBLOG_DIR})
    set(LIBLOG_DIR ${CMAKE_BINARY_DIR}/${LIBLOG_DIR})
endif()
if(NOT EXISTS ${LIBLOG_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBLOG_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBLOG_DIR")
endif()
if(NOT TARGET LibLog::library)
    add_subdirectory(${LIBLOG_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/liblog EXCLUDE_FROM_ALL)
endif()

set_default(API_LOGGER_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/api/logger)
if(NOT IS_ABSOLUTE ${API_LOGGER_DIR})
    set(API_LOGGER_DIR ${CMAKE_BINARY_DIR}/${API_LOGGER_DIR})
endif()
message(STATUS "API_LOGGER_DIR: ${API_LOGGER_DIR}")
if(NOT EXISTS ${API_LOGGER_DIR}/CMakeLists.cmake)
    message(FATAL_ERROR "${API_LOGGER_DIR}/CMakeLists.cmake does not exist; you need to pass -DAPI_LOGGER_DIR")
endif()
include("${API_LOGGER_DIR}/CMakeLists.cmake")

# XXX: Temporary server and api version variables trim (used in diagnostics api)
# Will be removed after api and impl. are changed to more relaxed format
string(STRIP "${API_VERSION}" API_VERSION)
string(REGEX MATCH "^([0-9]+.[0-9]+.[0-9]+)" API_VERSION ${API_VERSION})
message(STATUS "API_VERSION: ${API_VERSION}")

set_default(PACKAGE fred-logger-services)
set_default(HAVE_BOOST_SERIALIZATION 1)

set_default(VERSION ${PROJECT_VERSION})
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)

add_library(logger-core STATIC
    src/cfg.cc
    src/exceptions.cc
    src/is_monitoring_ip.cc
    src/handle_request.cc
    src/proto_wrap.cc
    src/proto_unwrap.cc)

add_library(LoggerCore::library ALIAS logger-core)

add_library(fred-logger-services-iface STATIC
    ${FRED_LOGGER_PROTO_SRCS}
    ${FRED_LOGGER_GRPC_SRCS})

add_library(FredLoggerServicesIface::library ALIAS fred-logger-services-iface)

target_link_libraries(fred-logger-services-iface
    gRPC::grpc++_reflection
    protobuf::libprotobuf)

set_grpc_properties_on_targets(
    fred-logger-services-iface)


target_link_libraries(logger-core
    FredLoggerServicesIface::library
    ${Boost_PROGRAM_OPTIONS_LIBRARY}
    ${Threads_LIBRARIES}
    LibLogger::library
    LibLog::library)

add_executable(fred-logger-services
    src/main.cc)

target_link_libraries(fred-logger-services PRIVATE
    LoggerCore::library)

set_common_properties_on_targets(
    fred-logger-services-iface
    fred-logger-services
    logger-core)

if(LOGGER_BUILD_TESTS)

add_subdirectory(test)

endif()

include(GNUInstallDirs)

install(TARGETS ${PACKAGE}
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

add_custom_target(uninstall
    COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
    COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

if(EXISTS ${CMAKE_SOURCE_DIR}/.git AND GIT_PROGRAM)
    if(NOT TARGET dist)
        add_custom_target(dist_api_logger
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/api/logger/ HEAD > ${CMAKE_BINARY_DIR}/.api-logger.tar
            WORKING_DIRECTORY ${API_LOGGER_DIR})
        if (NOT TARGET dist_liblogger)
            add_custom_target(dist_liblogger
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblogger/ HEAD > ${CMAKE_BINARY_DIR}/.liblogger.tar
                WORKING_DIRECTORY ${LIBLOGGER_DIR})
            add_custom_target(dist_liblog
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblog/ HEAD > ${CMAKE_BINARY_DIR}/.liblog.tar
                WORKING_DIRECTORY ${LIBLOG_DIR})
            add_custom_target(dist_liblog_spdlog
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblog/3rd_party/lib/spdlog/ HEAD > ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                WORKING_DIRECTORY ${LIBLOG_DIR}/3rd_party/lib/spdlog/)
            add_custom_target(dist
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.api-logger.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblogger.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblog.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                COMMAND cat ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar | gzip > ${CMAKE_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz
                COMMAND rm ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.api-logger.tar ${CMAKE_BINARY_DIR}/.liblogger.tar ${CMAKE_BINARY_DIR}/.liblog.tar ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                DEPENDS dist_api_logger dist_liblogger dist_liblog dist_liblog_spdlog
                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
        else()
            add_custom_target(dist
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.api-logger.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblogger.tar
                COMMAND cat ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar | gzip > ${CMAKE_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz
                COMMAND rm ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.api-logger.tar ${CMAKE_BINARY_DIR}/.liblogger.tar
                DEPENDS dist_api_logger dist_liblogger
                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
        endif()
    endif()

    if(DEFINED ENV{DISTCHECK_CMAKE_FLAGS})
        set(distcheck_flags $ENV{DISTCHECK_CMAKE_FLAGS})
    endif()

    if(NOT TARGET distcheck)
        set(DISTCHECK_BUILD_DIR "_build")
        set(DISTCHECK_INSTALL_DIR "_inst")
        if(${CMAKE_GENERATOR} STREQUAL "Ninja")
            set(DISTCHECK_BUILD_CMD "ninja")
        else()
            set(DISTCHECK_BUILD_CMD "$(MAKE)")
        endif()
        add_custom_target(clean_before_distcheck
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            COMMENT "cleaning before distcheck start")
        add_custom_target(distcheck_make_dirs
            COMMAND mkdir ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR}
            COMMENT "make distcheck build and install directories"
            DEPENDS clean_before_distcheck)
        add_custom_target(distcheck_unpack_archive
            COMMAND tar xzf ${TARBALL_FILE_NAME}.tar.gz
            COMMENT "Checking the distribution archive..."
            DEPENDS dist distcheck_make_dirs)
        add_custom_target(distcheck_configure
            COMMAND ${CMAKE_COMMAND} -G${CMAKE_GENERATOR} ${distcheck_flags} -DSERVER_VERSION=${SERVER_VERSION} -DCMAKE_INSTALL_PREFIX=../${DISTCHECK_INSTALL_DIR} ../${TARBALL_FILE_NAME}
            COMMENT "configure distcheck"
            DEPENDS distcheck_unpack_archive
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_make
            COMMAND ${DISTCHECK_BUILD_CMD}
            COMMENT "make"
            DEPENDS distcheck_configure
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_install
            COMMAND ${DISTCHECK_BUILD_CMD} install
            COMMENT "make install"
            DEPENDS distcheck_make
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_uninstall
            COMMAND ${DISTCHECK_BUILD_CMD} uninstall
            COMMENT "make uninstall"
            DEPENDS distcheck_install
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_clean
            COMMAND ${DISTCHECK_BUILD_CMD} clean
            COMMENT "make clean"
            DEPENDS distcheck_uninstall
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            COMMENT "PASS: '${TARBALL_FILE_NAME}.tar.gz' is ready for distribution."
            DEPENDS distcheck_clean)
    endif()
else()
    message(STATUS "no git -- not including dist and distcheck targets")
endif()
