cmake_minimum_required(VERSION 3.5)

find_program(GIT_PROGRAM git)
find_program(CCACHE_PROGRAM ccache)
find_program(IDL_PROGRAM omniidl)

option(LOGGER_BUILD_TESTS "Build logger tests" OFF)

set(SERVER_VERSION "1.1.0")
if(NOT SERVER_VERSION)
    if(NOT GIT_PROGRAM)
        message(FATAL_ERROR "git not found; you need to pass -DSERVER_VERSION=")
    endif()
    execute_process(COMMAND ${GIT_PROGRAM} "describe" "--tags"
                    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
                    OUTPUT_VARIABLE SERVER_VERSION)
endif()
string(STRIP "${SERVER_VERSION}" SERVER_VERSION)

message(STATUS "SERVER_VERSION: ${SERVER_VERSION}")

string(REGEX MATCH "^([0-9]+.[0-9]+.[0-9]+)" SERVER_VERSION ${SERVER_VERSION})
project(FredLoggerCorba
    VERSION ${SERVER_VERSION}
    LANGUAGES CXX)
message(STATUS "PROJECT_VERSION: ${PROJECT_VERSION}")

if(CCACHE_PROGRAM)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

set(TARBALL_FILE_NAME "${PROJECT_NAME}-${SERVER_VERSION}")
set(LIBLOGGER_PREFIX ${TARBALL_FILE_NAME}/external/lib/liblogger)

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

set_default(CMAKE_BUILD_TYPE "Release")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set_default(THREADS_PREFER_PTHREAD_FLAG ON)
set_default(SPDLOG_ACTIVE_LEVEL 0)
set_default(FMT_STRING_ALIAS 1)
set_default(FMT_HEADER_ONLY 1)
set_default(CMAKE_EXPORT_COMPILE_COMMANDS ON)

find_package(Threads REQUIRED)
set(Threads_LIBRARIES Threads::Threads)

find_package(Boost 1.53.0
    COMPONENTS
        program_options
        date_time
    REQUIRED)

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PUBLIC
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
        target_compile_definitions(${target_name}
            PRIVATE
                SPDLOG_ACTIVE_LEVEL=${SPDLOG_ACTIVE_LEVEL}
                FMT_STRING_ALIAS=${FMT_STRING_ALIAS}
                FMT_HEADER_ONLY=${FMT_HEADER_ONLY})
    endforeach()
endfunction()

function(set_idl_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting idl properties on: " ${target_name})
        target_compile_options(${target_name}
            PRIVATE
                "-Wno-unused-parameter"
                "-Wno-unused-variable")
    endforeach()
endfunction()

set_default(LIBLOGGER_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/liblogger)
if(NOT IS_ABSOLUTE ${LIBLOGGER_DIR})
    set(LIBLOGGER_DIR ${CMAKE_BINARY_DIR}/${LIBLOGGER_DIR})
endif()
if(NOT EXISTS ${LIBLOGGER_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBLOGGER_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBLOGGER_DIR")
endif()
if(NOT TARGET LibLogger::library)
    add_subdirectory(${LIBLOGGER_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/liblogger EXCLUDE_FROM_ALL)
endif()

set_default(LIBLOG_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/liblog)
if(NOT IS_ABSOLUTE ${LIBLOG_DIR})
    set(LIBLOG_DIR ${CMAKE_BINARY_DIR}/${LIBLOG_DIR})
endif()
if(NOT EXISTS ${LIBLOG_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBLOG_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBLOG_DIR")
endif()
message(STATUS "LIBLOG_DIR: ${LIBLOG_DIR}")
if(NOT TARGET LibLog::library)
    add_subdirectory(${LIBLOG_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/liblog EXCLUDE_FROM_ALL)
endif()

set_default(LIBPG_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/libpg)
if(NOT IS_ABSOLUTE ${LIBPG_DIR})
    set(LIBPG_DIR ${CMAKE_BINARY_DIR}/${LIBPG_DIR})
endif()
if(NOT EXISTS ${LIBPG_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBPG_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBPG_DIR")
endif()
message(STATUS "LIBPG_DIR: ${LIBPG_DIR}")
if(NOT TARGET LibPg::library)
    add_subdirectory(${LIBPG_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/libpg EXCLUDE_FROM_ALL)
endif()

set_default(IDL_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/idl)
message(STATUS "IDL_DIR: ${IDL_DIR}")

find_package(PkgConfig REQUIRED)

pkg_search_module(OMNIORB4 REQUIRED omniORB4>=4.1.2)
pkg_search_module(OMNIDYNAMIC4 REQUIRED omniDynamic4>=4.1.2)

include(CheckIncludeFileCXX)
function(abort_if_headers_not_found)
    foreach(header_name ${ARGN})
        check_include_file_cxx(${header_name} FOUND${header_name})
        if(NOT FOUND${header_name})
            message(FATAL_ERROR "Header ${header_name} not found!")
        endif()
    endforeach()
endfunction()

set(Resolv_LIBRARIES resolv)
set(Rt_LIBRARIES rt)

function(target_link_external_libraries target_name)
    foreach(library_name ${ARGN})
        target_link_libraries(${target_name} "${${linker_info_${library_name}}}")
    endforeach()
endfunction()

macro(store_linker_info key value)
    set(linker_info_${key} "${value}")
endmacro()

store_linker_info(omniorb4 OMNIORB4_LIBRARIES)
store_linker_info(omnidynamic4 OMNIDYNAMIC4_LIBRARIES)

function(compile_idl_files)
    message(STATUS "Compiling idl...")
    if(NOT IDL_PROGRAM)
        message(FATAL_ERROR "omniidl not found")
    endif()
    execute_process(
        COMMAND mkdir -p src/corba
        WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
    foreach(idl_name ${ARGN})
        if(NOT EXISTS ${IDL_DIR}/idl/${idl_name}.idl)
            message(FATAL_ERROR "${IDL_DIR}/idl/${idl_name}.idl does not exist; you need to pass -DIDL_DIR")
        endif()
        execute_process(
            COMMAND ${IDL_PROGRAM} -bcxx -Wbuse_quotes -Wba -C ./src/corba ${IDL_DIR}/idl/${idl_name}.idl
            WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
            OUTPUT_VARIABLE OMNIIDL_MESSAGE${idl_name})
        message(STATUS ${OMNIIDL_MESSAGE}${idl_name})
    endforeach()
    message(STATUS "...done")
endfunction()

set_default(PACKAGE fred-logger-corba)
set_default(HAVE_BOOST_SERIALIZATION 1)

set_default(VERSION ${PROJECT_VERSION})
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)

add_library(logger-core STATIC
    src/args.cc
    src/cfg.cc
    src/corba_unwrap.cc
    src/corba_wrap.cc
    src/exceptions.cc
    src/get_dsn.cc
    src/is_monitoring_ip.cc
    src/log_entry_cache.cc
    src/log_entry_type_cache.cc
    src/nameservice.cc
    src/service_cache.cc
    src/session_cache.cc
    src/request/close_log_entry.cc
    src/request/close_session.cc
    src/request/create_log_entry.cc
    src/request/create_session.cc
    src/request/get_log_entry_types.cc
    src/request/get_request_count_users.cc
    src/request/get_object_reference_types.cc
    src/request/get_results.cc
    src/request/get_services.cc
    src/util.cc
    src/legacy/corba_container.cc)

add_library(LoggerCore::library ALIAS logger-core)

add_library(fred-logger-corba-idl STATIC
    src/corba/LoggerSK.cc
    src/corba/LoggerDynSK.cc
    src/corba/AdminSK.cc
    src/corba/AdminDynSK.cc
    src/corba/RegistrySK.cc
    src/corba/RegistryDynSK.cc
    src/corba/FiltersSK.cc
    src/corba/FiltersDynSK.cc
    src/corba/_dataTypesSK.cc
    src/corba/_dataTypesDynSK.cc
    src/corba/DateTimeSK.cc
    src/corba/DateTimeDynSK.cc)

add_library(FredLoggerCorbaIdl::library ALIAS fred-logger-corba-idl)

target_link_external_libraries(fred-logger-corba-idl
    omniorb4
    omnidynamic4)

target_link_libraries(logger-core
    FredLoggerCorbaIdl::library
    ${Boost_PROGRAM_OPTIONS_LIBRARY}
    ${Threads_LIBRARIES}
    LibLogger::library
    LibPg::library
    LibLog::library)

add_executable(fred-logger-corba
    src/main.cc)

target_link_libraries(fred-logger-corba PRIVATE
    LoggerCore::library)

set_common_properties_on_targets(
    fred-logger-corba-idl
    fred-logger-corba
    logger-core)

set_idl_properties_on_targets(
    fred-logger-corba-idl)

compile_idl_files(
    Logger
    Admin
    Registry
    Filters
    _dataTypes
    DateTime)

if(LOGGER_BUILD_TESTS)

add_subdirectory(test)

endif()

include(GNUInstallDirs)

install(TARGETS ${PACKAGE}
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

add_custom_target(uninstall
    COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
    COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

if(EXISTS ${CMAKE_SOURCE_DIR}/.git AND GIT_PROGRAM)
    if(NOT TARGET dist)
        add_custom_target(dist_idl
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/idl/ HEAD > ${CMAKE_BINARY_DIR}/.idl.tar
            WORKING_DIRECTORY ${IDL_DIR})
        if (NOT TARGET dist_liblogger)
            add_custom_target(dist_liblogger
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblogger/ HEAD > ${CMAKE_BINARY_DIR}/.liblogger.tar
                WORKING_DIRECTORY ${LIBLOGGER_DIR})
            add_custom_target(dist_libpg
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/libpg/ HEAD > ${CMAKE_BINARY_DIR}/.libpg.tar
                WORKING_DIRECTORY ${LIBPG_DIR})
            add_custom_target(dist_liblog
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblog/ HEAD > ${CMAKE_BINARY_DIR}/.liblog.tar
                WORKING_DIRECTORY ${LIBLOG_DIR})
            add_custom_target(dist_liblog_spdlog
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblog/3rd_party/lib/spdlog/ HEAD > ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                WORKING_DIRECTORY ${LIBLOG_DIR}/3rd_party/lib/spdlog/)
            add_custom_target(dist
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.idl.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblogger.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.libpg.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblog.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                COMMAND cat ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar | gzip > ${CMAKE_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz
                COMMAND rm ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.idl.tar ${CMAKE_BINARY_DIR}/.liblogger.tar ${CMAKE_BINARY_DIR}/.libpg.tar ${CMAKE_BINARY_DIR}/.liblog.tar ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                DEPENDS dist_idl dist_liblogger dist_libpg dist_liblog dist_liblog_spdlog
                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
        else()
            add_custom_target(dist
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.idl.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblogger.tar
                COMMAND cat ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar | gzip > ${CMAKE_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz
                COMMAND rm ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.idl.tar ${CMAKE_BINARY_DIR}/.liblogger.tar
                DEPENDS dist_idl dist_liblogger
                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
        endif()
    endif()

    if(DEFINED ENV{DISTCHECK_CMAKE_FLAGS})
        set(distcheck_flags $ENV{DISTCHECK_CMAKE_FLAGS})
    endif()

    if(NOT TARGET distcheck)
        set(DISTCHECK_BUILD_DIR "_build")
        set(DISTCHECK_INSTALL_DIR "_inst")
        if(${CMAKE_GENERATOR} STREQUAL "Ninja")
            set(DISTCHECK_BUILD_CMD "ninja")
        else()
            set(DISTCHECK_BUILD_CMD "$(MAKE)")
        endif()
        add_custom_target(clean_before_distcheck
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            COMMENT "cleaning before distcheck start")
        add_custom_target(distcheck_make_dirs
            COMMAND mkdir ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR}
            COMMENT "make distcheck build and install directories"
            DEPENDS clean_before_distcheck)
        add_custom_target(distcheck_unpack_archive
            COMMAND tar xzf ${TARBALL_FILE_NAME}.tar.gz
            COMMENT "Checking the distribution archive..."
            DEPENDS dist distcheck_make_dirs)
        add_custom_target(distcheck_configure
            COMMAND ${CMAKE_COMMAND} -G${CMAKE_GENERATOR} ${distcheck_flags} -DSERVER_VERSION=${SERVER_VERSION} -DCMAKE_INSTALL_PREFIX=../${DISTCHECK_INSTALL_DIR} ../${TARBALL_FILE_NAME}
            COMMENT "configure distcheck"
            DEPENDS distcheck_unpack_archive
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_make
            COMMAND ${DISTCHECK_BUILD_CMD}
            COMMENT "make"
            DEPENDS distcheck_configure
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_install
            COMMAND ${DISTCHECK_BUILD_CMD} install
            COMMENT "make install"
            DEPENDS distcheck_make
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_uninstall
            COMMAND ${DISTCHECK_BUILD_CMD} uninstall
            COMMENT "make uninstall"
            DEPENDS distcheck_install
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_clean
            COMMAND ${DISTCHECK_BUILD_CMD} clean
            COMMENT "make clean"
            DEPENDS distcheck_uninstall
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            COMMENT "PASS: '${TARBALL_FILE_NAME}.tar.gz' is ready for distribution."
            DEPENDS distcheck_clean)
    endif()
else()
    message(STATUS "no git -- not including dist and distcheck targets")
endif()
