# Copyright (C) 2020  CZ.NIC, z. s. p. o.
#
# This file is part of FRED.
#
# FRED is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# FRED is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with FRED.  If not, see <https://www.gnu.org/licenses/>.

cmake_minimum_required(VERSION 3.5)

find_program(CCACHE_PROGRAM ccache)

option(LIBDIAGNOSTICS_BUILD_TESTS "Build libdiagnostics tests" OFF)

if(CCACHE_PROGRAM)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

set(LIBDIAGNOSTICS_VERSION "1.0.0")
project(LibDiagnostics
    VERSION ${LIBDIAGNOSTICS_VERSION}
    LANGUAGES CXX)

message(STATUS "${PROJECT_NAME} version: ${PROJECT_VERSION}")

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

set_default(CMAKE_BUILD_TYPE "Release")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set_default(THREADS_PREFER_PTHREAD_FLAG ON)
set_default(SPDLOG_ACTIVE_LEVEL 0)
set_default(FMT_STRING_ALIAS 1)
set_default(FMT_HEADER_ONLY 1)
set_default(CMAKE_EXPORT_COMPILE_COMMANDS ON)

find_package(Threads REQUIRED)

find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
        system
    REQUIRED)

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
        target_include_directories(${target_name}
            PUBLIC
                $<INSTALL_INTERFACE:include>
                $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
                $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
                ${PostgreSQL_INCLUDE_DIRS}
            PRIVATE
                ${CMAKE_CURRENT_SOURCE_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
        target_compile_definitions(${target_name}
            PRIVATE
                SPDLOG_ACTIVE_LEVEL=${SPDLOG_ACTIVE_LEVEL}
                FMT_STRING_ALIAS=${FMT_STRING_ALIAS}
                FMT_HEADER_ONLY=${FMT_HEADER_ONLY})
    endforeach()
endfunction()

function(set_grpc_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_compile_options(${target_name}
            PRIVATE
                "-Wno-unused-parameter")
        target_link_libraries(${target_name}
            PUBLIC
                -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state
                protobuf::libprotobuf)
    endforeach()
endfunction()

get_directory_property(LIBDIAGNOSTICS_HAS_PARENT PARENT_DIRECTORY)

set_default(API_DIAGNOSTICS_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/api/diagnostics)
if(NOT IS_ABSOLUTE ${API_DIAGNOSTICS_DIR})
    set(API_DIAGNOSTICS_DIR ${CMAKE_BINARY_DIR}/${API_DIAGNOSTICS_DIR})
endif()
message(STATUS "API_DIAGNOSTICS_DIR: ${API_DIAGNOSTICS_DIR}")
if(NOT EXISTS ${API_DIAGNOSTICS_DIR}/CMakeLists.cmake)
    message(FATAL_ERROR "${API_DIAGNOSTICS_DIR}/CMakeLists.cmake does not exist; you need to pass -DAPI_DIAGNOSTICS_DIR")
endif()
if (LIBDIAGNOSTICS_HAS_PARENT)
    set(API_DIAGNOSTICS_DIR ${API_DIAGNOSTICS_DIR} PARENT_SCOPE)
endif()
include("${API_DIAGNOSTICS_DIR}/CMakeLists.cmake")

if (LIBDIAGNOSTICS_HAS_PARENT)
    set(LIBDIAGNOSTICS_VERSION ${LIBDIAGNOSTICS_VERSION} PARENT_SCOPE)
    set(LIBDIAGNOSTICS_API_DIAGNOSTICS_VERSION ${API_DIAGNOSTICS_VERSION} PARENT_SCOPE)
endif()

set_default(HAVE_BOOST_SERIALIZATION 1)

configure_file(${CMAKE_CURRENT_SOURCE_DIR}/diagnostics.pc.in ${CMAKE_CURRENT_BINARY_DIR}/diagnostics.pc @ONLY)
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)

add_library(fred-diagnostics-services-iface STATIC
    ${FRED_DIAGNOSTICS_PROTO_SRCS}
    ${FRED_DIAGNOSTICS_GRPC_SRCS})

add_library(FredDiagnosticsServicesIface::library ALIAS fred-diagnostics-services-iface)

set_grpc_properties_on_targets(
    fred-diagnostics-services-iface)

add_library(diagnostics STATIC
    src/diagnostics.cc
    src/proto_wrap.cc)

add_library(LibDiagnostics::library ALIAS diagnostics)

target_link_libraries(diagnostics
    Boost::program_options
    Threads::Threads
    FredDiagnosticsServicesIface::library)

set_common_properties_on_targets(
    diagnostics
    fred-diagnostics-services-iface)

export(TARGETS fred-diagnostics-services-iface FILE CMakeFiles-api.cmake)

if(LIBDIAGNOSTICS_BUILD_TESTS)

add_subdirectory(test)

endif()

find_program(GIT_PROGRAM git)
if("${LIBDIAGNOSTICS_HAS_PARENT}" STREQUAL "")

    include(GNUInstallDirs)

    install(TARGETS diagnostics
        LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})

    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

    if(EXISTS ${CMAKE_SOURCE_DIR}/.git AND GIT_PROGRAM)
        string(TOLOWER "${PROJECT_NAME}-${PROJECT_VERSION}" TARBALL_FILE_NAME)
        message("TARBALL_FILE_NAME: ${TARBALL_FILE_NAME}")
        if(NOT TARGET dist)
            add_custom_target(dist_libdiagnostics_api_diagnostics
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/api/diagnostics/ HEAD > ${CMAKE_BINARY_DIR}/.libdiagnostics.api-diagnostics.tar
                WORKING_DIRECTORY ${API_DIAGNOSTICS_DIR})
            add_custom_target(dist
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
                COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.libdiagnostics.api-diagnostics.tar && rm ${CMAKE_BINARY_DIR}/.libdiagnostics.api-diagnostics.tar
                COMMAND cat ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar | gzip > ${CMAKE_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz && rm ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
                DEPENDS dist_libdiagnostics_api_diagnostics
                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
        endif()

        if(DEFINED ENV{DISTCHECK_CMAKE_FLAGS})
            set(distcheck_flags $ENV{DISTCHECK_CMAKE_FLAGS})
        endif()

        if(NOT TARGET distcheck)
            set(DISTCHECK_BUILD_DIR "_build")
            set(DISTCHECK_INSTALL_DIR "_inst")
            if(${CMAKE_GENERATOR} STREQUAL "Ninja")
                set(DISTCHECK_BUILD_CMD "ninja")
            else()
                set(DISTCHECK_BUILD_CMD "$(MAKE)")
            endif()
            add_custom_target(clean_before_distcheck
                COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
                COMMENT "cleaning before distcheck start")
            add_custom_target(distcheck_make_dirs
                COMMAND mkdir ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR}
                COMMENT "make distcheck build and install directories"
                DEPENDS clean_before_distcheck)
            add_custom_target(distcheck_unpack_archive
                COMMAND tar xzf ${TARBALL_FILE_NAME}.tar.gz
                COMMENT "Checking the distribution archive..."
                DEPENDS dist distcheck_make_dirs)
            add_custom_target(distcheck_configure
                COMMAND ${CMAKE_COMMAND} -G${CMAKE_GENERATOR} ${distcheck_flags} -DCMAKE_INSTALL_PREFIX=../${DISTCHECK_INSTALL_DIR} ../${TARBALL_FILE_NAME}
                COMMENT "configure distcheck"
                DEPENDS distcheck_unpack_archive
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck_make
                COMMAND ${DISTCHECK_BUILD_CMD}
                COMMENT "make"
                DEPENDS distcheck_configure
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck_install
                COMMAND ${DISTCHECK_BUILD_CMD} install
                COMMENT "make install"
                DEPENDS distcheck_make
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck_uninstall
                COMMAND ${DISTCHECK_BUILD_CMD} uninstall
                COMMENT "make uninstall"
                DEPENDS distcheck_install
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck_clean
                COMMAND ${DISTCHECK_BUILD_CMD} clean
                COMMENT "make clean"
                DEPENDS distcheck_uninstall
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck
                COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
                COMMENT "PASS: '${TARBALL_FILE_NAME}.tar.gz' is ready for distribution."
                DEPENDS distcheck_clean)
        endif()
    else()
        message(STATUS "no git -- not including dist and distcheck targets")
    endif()
elseif(EXISTS ${CMAKE_SOURCE_DIR}/.git AND GIT_PROGRAM)
    if(NOT TARGET dist_libdiagnostics)
        message(STATUS "LIBDIAGNOSTICS_PREFIX: ${LIBDIAGNOSTICS_PREFIX}")
        add_custom_target(dist_libdiagnostics_api_diagnostics
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${LIBDIAGNOSTICS_PREFIX}/external/api/diagnostics/ HEAD > ${CMAKE_BINARY_DIR}/.libdiagnostics.api_diagnostics.tar
            WORKING_DIRECTORY ${API_DIAGNOSTICS_DIR})
        add_custom_target(dist_libdiagnostics
            COMMAND ${GIT_PROGRAM} -C ${CMAKE_CURRENT_SOURCE_DIR} archive --format=tar --prefix=${LIBDIAGNOSTICS_PREFIX}/ HEAD > ${CMAKE_BINARY_DIR}/.libdiagnostics.tar
            COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.libdiagnostics.tar ${CMAKE_BINARY_DIR}/.libdiagnostics.api_diagnostics.tar && rm ${CMAKE_BINARY_DIR}/.libdiagnostics.api_diagnostics.tar
            DEPENDS dist_libdiagnostics_api_diagnostics
            WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
    endif()
endif()
