cmake_minimum_required(VERSION 3.5)

# macros

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

# project details

include("cmake/package.cmake")

package(fred-akm-ng
    FULL_VERSION "1.1.5")

project(FredAkm
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

# build options

#option(AKM_BUILD_TESTS "Build akm tests" OFF)

# compile options

find_program(CCACHE_PROGRAM ccache)
if(CCACHE_PROGRAM)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

set_default(CMAKE_BUILD_TYPE "Release")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set_default(THREADS_PREFER_PTHREAD_FLAG ON)
set_default(CMAKE_EXPORT_COMPILE_COMMANDS ON)
set(DEFAULT_FRED_AKM_NG_CONFIG_FILE "/etc/fred/fred-akm-ng.conf" CACHE STRING "Specifies the default location of fred-akm-ng configuration file")

# dependencies

find_package(Threads REQUIRED)

find_package(Boost 1.66.0
    COMPONENTS
        system
        program_options
        date_time
    REQUIRED)

# package dependencies

include("cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "dependencies.txt")

# configuration files

set_default(HAVE_LOGGER 1)

configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)

# build

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PUBLIC
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
    endforeach()
endfunction()

function(set_grpc_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_compile_options(${target_name}
            PRIVATE "-Wno-unused-parameter")
    endforeach()
endfunction()

add_library(fred-akm-core STATIC
    src/acceptable_keyset.cc
    src/cfg.cc
    src/domain.cc
    src/export_scan_tasks.cc
    src/keyset.cc
    src/scan_type.cc
    src/update.cc
    src/grpc_client/get_acceptable_keysets.cc
    src/grpc_client/export_scan_tasks.cc
    src/grpc_client/make_stub.cc
    src/grpc_client/proto_unwrap.cc
    src/grpc_client/proto_wrap.cc
    src/database/check_configuration.cc
    src/database/process_acceptable_keysets.cc
    src/database/impl/add_keyset.cc
    src/database/impl/is_domain_ok_for_update.cc
    src/database/impl/is_keyset_ok_for_update.cc
    src/database/impl/extended_info_domain_data.cc
    src/database/impl/turn_off_dnssec.cc
    src/database/impl/update_keyset.cc
    src/logger/log_entry.cc
    src/logger/log_entry_factory.cc
    src/logger/impl/log_entry_type.cc
    src/logger/impl/to_log_entry_property.cc
    src/logger/impl/to_object_reference.cc)

add_library(FredAkmCore::library ALIAS fred-akm-core)

add_library(fred-akm-iface STATIC
    ${CDNSKEY_PROCESSOR_PROTO_SRCS}
    ${CDNSKEY_PROCESSOR_GRPC_SRCS})

add_library(FredAkmIface::library ALIAS fred-akm-iface)

target_link_libraries(fred-akm-iface
    -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state
    protobuf::libprotobuf)

set_grpc_properties_on_targets(
    fred-akm-iface)

target_link_libraries(fred-akm-core
    Boost::system
    Boost::program_options
    Boost::date_time
    dl
    Threads::Threads
    FredAkmIface::library
    LibStrong::library
    Fred::library
    LibLog::library
    LibGrill::library
    gRPC::grpc++)

add_executable(fred-akm-ng
    src/main.cc)

target_link_libraries(fred-akm-ng PRIVATE
    FredAkmCore::library)

set_common_properties_on_targets(
    fred-akm-ng
    fred-akm-iface
    fred-akm-core)

# TODO: tests

#if(AKM_BUILD_TESTS)
#    add_subdirectory(test)
#endif()

# installation

include(GNUInstallDirs)

install(TARGETS ${PACKAGE_NAME}
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

add_custom_target(uninstall
    COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
    COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

# dist

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")
