cmake_minimum_required(VERSION 3.5)

# build options

option(THREADS_PREFER_PTHREAD_FLAG "The -pthread compiler and linker flag preference." TRUE)
option(CMAKE_EXPORT_COMPILE_COMMANDS "If enabled, generates a compile_commands.json file containing the exact compiler calls." ON)
set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Specifies the build type. Possible values are empty, Debug, Release, RelWithDebInfo, MinSizeRel, ...")

# project details

include("cmake/package.cmake")

package(fred-bulk-transfer FULL_VERSION "2.1.0")

project(FredBulkTransfer
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

# package dependencies

include("cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "dependencies.txt")

# dependencies

find_program(PYTHON_PROGRAM python3)

set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
find_package(Threads REQUIRED)
find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
    REQUIRED)
find_package(PkgConfig REQUIRED)

set_default(PACKAGE fred-bulk-transfer)
set_default(HAVE_BOOST_SERIALIZATION 1)
set_default(HAVE_LOGGER 1)

# configuration files

configure_file(config.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)

# build

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PUBLIC
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PUBLIC "-ggdb"
            PUBLIC "-grecord-gcc-switches"
            PUBLIC "-Wall"
            PUBLIC "-Wextra"
            PUBLIC "-fdiagnostics-color=auto")
    endforeach()
endfunction()


set(BULK_TRANSFER_SOURCES
    src/args.cc
    src/args_output.cc
    src/authinfo.cc
    src/bulk_transfer.cc
    src/main.cc
)

add_library(bulk-transfer-static STATIC ${BULK_TRANSFER_SOURCES})
add_library(bulk-transfer-static::library ALIAS bulk-transfer-static)

target_link_libraries(bulk-transfer-static
PUBLIC
    Threads::Threads
PRIVATE
    Boost::program_options
    Boost::date_time
    Fred::library
)

add_executable(fred-bulk-transfer
    src/main.cc)

target_link_libraries(fred-bulk-transfer
PRIVATE
    bulk-transfer-static::library
    Threads::Threads
    Boost::program_options
    Boost::date_time
    Fred::library
)
#include_directories(${LIBFRED_INCLUDE_DIR})

set_common_properties_on_targets(
    fred-bulk-transfer
    bulk-transfer-static)

# installation

include(GNUInstallDirs)

install(TARGETS fred-bulk-transfer
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

get_directory_property(HAS_PARENT "PARENT_DIRECTORY")
if(NOT HAS_PARENT)
    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)
endif()

# dist

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_PREFIX "${FRED-BULK-TRANSFER_PREFIX}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")

list_package_dependencies_recursive("${PACKAGE_NAME}")
