cmake_minimum_required(VERSION 3.5)

# macros

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

macro(append_path output_variable_name)
    foreach(ARG ${ARGN})
        if(${output_variable_name})
            string(APPEND ${output_variable_name} "/${ARG}")
        else()
            set(${output_variable_name} "${ARG}")
        endif()
    endforeach()
    string(REGEX REPLACE "//+" "/" ${output_variable_name} "${${output_variable_name}}")
    string(REGEX REPLACE "(.)/$" "\\1" ${output_variable_name} "${${output_variable_name}}")
endmacro()

macro(concat_path output_variable_name)
    set(concat_path_tmp_variable "")
    append_path(concat_path_tmp_variable ${ARGN})
    set(${output_variable_name} "${concat_path_tmp_variable}" PARENT_SCOPE)
endmacro()

macro(set_default_path variable_name)
    if(NOT ${variable_name})
        set(${variable_name} "")
        append_path(${variable_name} ${ARGN})
    endif()
endmacro()

# project details

include("cmake/package.cmake")

package(fred-zone-services
    FULL_VERSION "1.0.1")

project(FredZoneServices
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

# build options

option(THREADS_PREFER_PTHREAD_FLAG "The -pthread compiler and linker flag preference." TRUE)
option(CMAKE_EXPORT_COMPILE_COMMANDS "If enabled, generates a compile_commands.json file containing the exact compiler calls." ON)
option(ZONE_BUILD_TESTS "Build ${PACKAGE_NAME} tests" OFF)
option(ZONE_CLIENT_BUILD "Build fred-zone-generator" OFF)

# compile options

set_default(CMAKE_BUILD_TYPE "Release")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set(SPDLOG_ACTIVE_LEVEL "SPDLOG_LEVEL_TRACE" CACHE STRING "This will turn on/off logging statements at compile time.")
set(FMT_STRING_ALIAS "1" CACHE STRING "Constructs a compile-time format string.")
set(FMT_HEADER_ONLY "1" CACHE STRING "Use fmt library in the header-only manner.")

# package dependencies

include("cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "dependencies.txt")

# dependencies

find_package(Threads REQUIRED)

set(CMAKE_FIND_PACKAGE_PREFER_CONFIG TRUE)
find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
    REQUIRED)

find_package(OpenSSL
    COMPONENTS
        Crypto
    REQUIRED)

include(CheckCXXSymbolExists)

set(CMAKE_REQUIRED_LIBRARIES OpenSSL::Crypto)
check_cxx_symbol_exists(EVP_MD_CTX_new "openssl/evp.h" HAVE_EVP_MD_CTX_NEW)
check_cxx_symbol_exists(EVP_MD_CTX_free "openssl/evp.h" HAVE_EVP_MD_CTX_FREE)
check_cxx_symbol_exists(EVP_MD_CTX_create "openssl/evp.h" HAVE_EVP_MD_CTX_CREATE)
check_cxx_symbol_exists(EVP_MD_CTX_destroy "openssl/evp.h" HAVE_EVP_MD_CTX_DESTROY)
if((NOT HAVE_EVP_MD_CTX_NEW AND NOT HAVE_EVP_MD_CTX_CREATE) OR
   (NOT HAVE_EVP_MD_CTX_FREE AND NOT HAVE_EVP_MD_CTX_DESTROY))
    message(FATAL_ERROR "no functions for EVP_MD_CTX* management")
endif()

# configuration files

set_default(HAVE_BOOST_SERIALIZATION 1)
set_default_path(DEFAULT_CONFIG_FILE "${CMAKE_INSTALL_FULL_SYSCONFDIR}" fred/fred-zone.conf)
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)

add_library(zone-lib STATIC
    src/impl/lib/absolute_fqdn.cc
    src/impl/lib/base64.cc
    src/impl/lib/dnskey_record.cc
    src/impl/lib/ds_record.cc
    src/impl/lib/exception.cc
    src/impl/lib/get_zone_data_context.cc
    src/impl/lib/get_zones.cc
    src/impl/lib/hash.cc
    src/impl/lib/wire_format.cc
    src/impl/lib/zone_data.cc
    src/impl/lib/detail/base64.cc)

add_library(ZoneLib::library ALIAS zone-lib)

target_link_libraries(zone-lib
PUBLIC
    LibPg::library
PRIVATE
    LibLog::library
    OpenSSL::Crypto)


add_library(zone-cfg STATIC
    src/cfg.cc)

add_library(ZoneCfg::library ALIAS zone-cfg)

target_link_libraries(zone-cfg
PUBLIC
    Boost::program_options
    LibLog::library
    LibStrong::library
    ZoneLib::library)


add_library(fred-zone-services-iface STATIC
    ${FRED_ZONE_PROTO_SRCS}
    ${FRED_ZONE_GRPC_SRCS})

add_library(FredZoneServicesIface::library ALIAS fred-zone-services-iface)

add_library(zone-core STATIC
    src/iface/zone_service.cc
    src/iface/tools/common_types_unwrappers.cc
    src/iface/tools/common_types_wrappers.cc
    src/iface/tools/tools.cc
    src/impl/zone_data.cc
    src/impl/zone_list.cc
    src/util/util.cc)

add_library(ZoneCore::library ALIAS zone-core)

target_link_libraries(zone-core
    FredZoneServicesIface::library
    Threads::Threads
    LibDiagnostics::library
    LibStrong::library
    ZoneCfg::library)


add_executable(fred-zone-services
    src/main.cc)

target_link_libraries(fred-zone-services PRIVATE
    FredDiagnosticsServicesIface::library
    ZoneCore::library
    ZoneLib::library)

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PUBLIC
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
        target_compile_definitions(${target_name}
            PRIVATE
                SPDLOG_ACTIVE_LEVEL=${SPDLOG_ACTIVE_LEVEL}
                FMT_STRING_ALIAS=${FMT_STRING_ALIAS}
                FMT_HEADER_ONLY=${FMT_HEADER_ONLY})
    endforeach()
endfunction()

function(set_grpc_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_compile_options(${target_name}
            PRIVATE
                "-Wno-unused-parameter"
                "-Wno-array-bounds")
        target_link_libraries(${target_name}
            PUBLIC
                -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state
                protobuf::libprotobuf)
    endforeach()
endfunction()

set_common_properties_on_targets(
    fred-zone-services-iface
    fred-zone-services
    zone-cfg
    zone-core
    zone-lib)

set_grpc_properties_on_targets(
    fred-zone-services-iface)

if(ZONE_CLIENT_BUILD)
    add_subdirectory(client)
endif()

# tests

if(ZONE_BUILD_TESTS)
    add_subdirectory(test)
endif()

include(GNUInstallDirs)

install(TARGETS ${PACKAGE_NAME}
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

add_custom_target(uninstall
    COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
    COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

# dist

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")

list_package_dependencies_recursive("${PACKAGE_NAME}")
