cmake_minimum_required(VERSION 3.5)

# build options

option(FRED_NOTIFY_OBJECT_STATE_CHANGES_BUILD_TESTS "Build ${PACKAGE_NAME} tests" OFF)
option(THREADS_PREFER_PTHREAD_FLAG "The -pthread compiler and linker flag preference." TRUE)
option(CMAKE_EXPORT_COMPILE_COMMANDS "If enabled, generates a compile_commands.json file containing the exact compiler calls." ON)

# compile options

set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Specifies the build type. Possible values are empty, Debug, Release, RelWithDebInfo, MinSizeRel, ...")
# CMAKE_<LANG>_FLAGS_<CONFIG> new in cmake version 3.11
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set(SPDLOG_ACTIVE_LEVEL "SPDLOG_LEVEL_TRACE" CACHE STRING "This will turn on/off logging statements at compile time.")
set(FMT_STRING_ALIAS "1" CACHE STRING "Constructs a compile-time format string.")
set(FMT_HEADER_ONLY "1" CACHE STRING "Use fmt library in the header-only manner.")

# project details

include("../../cmake/package.cmake")

package(fred-notify-object-state-changes
    FULL_VERSION "0.0.1")

project(FredNotifyObjectStateChanges
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

include(GNUInstallDirs)
set(FRED_NOTIFY_OBJECT_STATE_CHANGES_DEFAULT_CONFIG_FILE "${CMAKE_INSTALL_FULL_SYSCONFDIR}/fred/fred-notify-object-state-changes.conf" CACHE FILEPATH "Specifies the default location of runtime configuration file")

# package dependencies

include("../../cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "../../dependencies.txt")

# dependencies

find_package(Threads REQUIRED)

set(CMAKE_FIND_PACKAGE_PREFER_CONFIG TRUE)
find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
        system
    REQUIRED)

find_package(nlohmann_json 3.2.0 REQUIRED)

# configuration files

set(DEFAULT_CONFIG_FILE "${FRED_NOTIFY_OBJECT_STATE_CHANGES_DEFAULT_CONFIG_FILE}")
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)

# build

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PRIVATE
                ${CMAKE_SOURCE_DIR}
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR}
                ${LIBSTRONG_INCLUDE_DIRS})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
    endforeach()
endfunction()

add_library(fred-notify-object-state-changes-core STATIC
    src/cfg.cc
    src/cfg/database_options.cc
    src/cfg/exception.cc
    src/cfg/log_console_options.cc
    src/cfg/log_file_options.cc
    src/cfg/log_options.cc
    src/cfg/log_syslog_options.cc
    src/cfg/messenger_options.cc
    src/cfg/notification_options.cc
    src/cfg/util/make_color_mode.cc
    src/cfg/util/make_output_stream.cc
    src/cfg/util/make_severity.cc
    src/impl/exception.cc
    src/impl/notify_object_state_changes.cc
    src/impl/unwrap_uuid_from_psql.cc
    src/util/set_logging.cc
    src/util/util.cc)

add_library(FredNotifyObjectStateChangesCore::library ALIAS fred-notify-object-state-changes-core)

target_link_libraries(fred-notify-object-state-changes-core
    Threads::Threads
    Boost::program_options
    Boost::system
    LibHermes::library
    LibLog::library
    LibPg::library
    LibStrong::library
    nlohmann_json::nlohmann_json)

add_executable(fred-notify-object-state-changes
    src/main.cc)

target_link_libraries(fred-notify-object-state-changes PRIVATE
    FredNotifyObjectStateChangesCore::library)

set_common_properties_on_targets(
    fred-notify-object-state-changes
    fred-notify-object-state-changes-core)

# tests

if(FRED_NOTIFY_OBJECT_STATE_CHANGES_BUILD_TESTS)

add_subdirectory(test)

endif()

# installation

install(TARGETS ${PACKAGE_NAME}
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

get_directory_property(HAS_PARENT PARENT_DIRECTORY)
if(NOT HAS_PARENT)
    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)
endif()

# dist

include("../../cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")

get_directory_property(HAS_PARENT PARENT_DIRECTORY)
if(NOT HAS_PARENT)
    list_package_dependencies_recursive("${PACKAGE_NAME}")
endif()
