# Copyright (C) 2019-2020  CZ.NIC, z. s. p. o.
#
# This file is part of FRED.
#
# FRED is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# FRED is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with FRED.  If not, see <https://www.gnu.org/licenses/>.

cmake_minimum_required(VERSION 3.5)

find_program(GIT_PROGRAM git)
find_program(CCACHE_PROGRAM ccache)

if(NOT SERVER_VERSION)
    if(NOT GIT_PROGRAM)
        message(FATAL_ERROR "git not found; you need to pass -DSERVER_VERSION=")
    endif()
    execute_process(COMMAND ${GIT_PROGRAM} "describe" "--tags"
                    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
                    OUTPUT_VARIABLE SERVER_VERSION)
endif()
string(STRIP "${SERVER_VERSION}" SERVER_VERSION)

message(STATUS "SERVER_VERSION: ${SERVER_VERSION}")

if(CCACHE_PROGRAM)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

string(REGEX MATCH "^([0-9]+.[0-9]+.[0-9]+)" SERVER_VERSION_MAJOR_MINOR_PATCH ${SERVER_VERSION})
project(LibLog
    VERSION ${SERVER_VERSION_MAJOR_MINOR_PATCH}
    LANGUAGES CXX)
message(STATUS "PROJECT_VERSION: ${PROJECT_VERSION}")

set(TARBALL_FILE_NAME "${PROJECT_NAME}-${SERVER_VERSION}")

if("CXX" IN_LIST languages)
    message("C++ enabled")
endif()

include(GNUInstallDirs)

option(LIBLOG_BUILD_TESTS "Build liblog tests" OFF)

add_library(log
    STATIC
    src/liblog/context.cc
    src/liblog/impl/to_spdlog_level.cc
    src/liblog/impl/to_spdlog_pattern_time_type.cc
    src/liblog/log.cc
    src/liblog/log_config.cc
    src/liblog/sink/console_sink_config.cc
    src/liblog/sink/file_sink_config.cc
    src/liblog/sink/impl/console_sink.cc
    src/liblog/sink/impl/file_sink.cc
    src/liblog/sink/impl/syslog_sink.cc
    src/liblog/sink/syslog_sink_config.cc
    src/liblog/thread_number.cc)

add_library(LibLog::library ALIAS log)

set_target_properties(log PROPERTIES
    VERSION ${PROJECT_VERSION}
    CXX_STANDARD 14
    CXX_STANDARD_REQUIRED YES
    CXX_EXTENSIONS NO
    ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/lib"
    LIBRARY_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/lib"
    OUTPUT_NAME "log")

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

set(PACKAGE log)
set_default(HAVE_BOOST_SERIALIZATION 1)
set_default(SPDLOG_ACTIVE_LEVEL 0)
set_default(FMT_STRING_ALIAS 1)
set_default(FMT_HEADER_ONLY 1)
set_default(CMAKE_EXPORT_COMPILE_COMMANDS ON)

target_compile_options(log
    PRIVATE
        $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)

target_compile_definitions(log
    PUBLIC
        HAVE_BOOST_SERIALIZATION=${HAVE_BOOST_SERIALIZATION}
        SPDLOG_ACTIVE_LEVEL=${SPDLOG_ACTIVE_LEVEL}
        FMT_STRING_ALIAS=${FMT_STRING_ALIAS}
        FMT_HEADER_ONLY=${FMT_HEADER_ONLY})

set(VERSION ${PROJECT_VERSION})
configure_file(log.pc.in log.pc @ONLY)

find_package(Threads REQUIRED)
set(Threads_LIBRARIES Threads::Threads)
find_package(Boost 1.53.0
    COMPONENTS
        system
        thread
        serialization
        filesystem
    REQUIRED)
find_package(PkgConfig REQUIRED)

target_include_directories(log
    PUBLIC
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        $<INSTALL_INTERFACE:include>
    PRIVATE
        ${CMAKE_CURRENT_SOURCE_DIR}
        ${CMAKE_CURRENT_BINARY_DIR})

target_include_directories(log
    BEFORE
    PUBLIC
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/3rd_party/lib/spdlog/include>
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/3rd_party/lib/spdlog/include/spdlog>)

set(LIBLOG_LIBRARIES
    ${Threads_LIBRARIES}
    Boost::system
    Boost::thread)

target_link_libraries(log
    ${LIBLOG_LIBRARIES})

if(LIBLOG_BUILD_TESTS)

add_subdirectory(test/liblog)

endif()

get_directory_property(LIBLOG_HAS_PARENT PARENT_DIRECTORY)
if(LIBLOG_HAS_PARENT)
    set(${PROJECT_NAME}_LIBRARIES ${LIBLOG_LIBRARIES} PARENT_SCOPE)
endif()

if("${LIBLOG_HAS_PARENT}" STREQUAL "")

    include(GNUInstallDirs)

    install(TARGETS ${PACKAGE}
        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
        PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/log.pc DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/pkgconfig)

    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

    if(EXISTS ${CMAKE_SOURCE_DIR}/.git AND GIT_PROGRAM)
        if(NOT TARGET dist)
            if (NOT TARGET dist_liblog)
                add_custom_target(dist_liblog_spdlog
                    COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/3rd_party/lib/spdlog/ HEAD > ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/3rd_party/lib/spdlog/)
                add_custom_target(dist
                    COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
                    COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                    COMMAND cat ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar | gzip > ${CMAKE_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz
                    COMMAND rm ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                    DEPENDS dist_liblog_spdlog
                    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
            else()
                add_custom_target(dist
                    COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
                    COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.api-logger.tar
                    COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblogger.tar
                    COMMAND cat ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar | gzip > ${CMAKE_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz
                    COMMAND rm ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.api-logger.tar ${CMAKE_BINARY_DIR}/.liblogger.tar
                    DEPENDS dist_liblog
                    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
            endif()
        endif()

        if(DEFINED ENV{DISTCHECK_CMAKE_FLAGS})
            set(distcheck_flags $ENV{DISTCHECK_CMAKE_FLAGS})
        endif()

        if(NOT TARGET distcheck)
            set(DISTCHECK_BUILD_DIR "_build")
            set(DISTCHECK_INSTALL_DIR "_inst")
            if(${CMAKE_GENERATOR} STREQUAL "Ninja")
                set(DISTCHECK_BUILD_CMD "ninja")
            else()
                set(DISTCHECK_BUILD_CMD "$(MAKE)")
            endif()
            add_custom_target(clean_before_distcheck
                COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
                COMMENT "cleaning before distcheck start")
            add_custom_target(distcheck_make_dirs
                COMMAND mkdir ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR}
                COMMENT "make distcheck build and install directories"
                DEPENDS clean_before_distcheck)
            add_custom_target(distcheck_unpack_archive
                COMMAND tar xzf ${TARBALL_FILE_NAME}.tar.gz
                COMMENT "Checking the distribution archive..."
                DEPENDS dist distcheck_make_dirs)
            add_custom_target(distcheck_configure
                COMMAND ${CMAKE_COMMAND} -G${CMAKE_GENERATOR} ${distcheck_flags} -DSERVER_VERSION=${SERVER_VERSION} -DCMAKE_INSTALL_PREFIX=../${DISTCHECK_INSTALL_DIR} ../${TARBALL_FILE_NAME}
                COMMENT "configure distcheck"
                DEPENDS distcheck_unpack_archive
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck_make
                COMMAND ${DISTCHECK_BUILD_CMD}
                COMMENT "make"
                DEPENDS distcheck_configure
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck_install
                COMMAND ${DISTCHECK_BUILD_CMD} install
                COMMENT "make install"
                DEPENDS distcheck_make
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck_uninstall
                COMMAND ${DISTCHECK_BUILD_CMD} uninstall
                COMMENT "make uninstall"
                DEPENDS distcheck_install
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck_clean
                COMMAND ${DISTCHECK_BUILD_CMD} clean
                COMMENT "make clean"
                DEPENDS distcheck_uninstall
                WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
            add_custom_target(distcheck
                COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
                COMMENT "PASS: '${TARBALL_FILE_NAME}.tar.gz' is ready for distribution."
                DEPENDS distcheck_clean)
        endif()
    else()
        message(STATUS "no git -- not including dist and distcheck targets")
    endif()

endif()
